! ANSYS Script for Model on Day 36
! Small Sheet Metal Component

/PREP7  


! Element and Materials

ET,1,PLANE82
ET,2,CONTAC26
ET,3,LINK1
R,1,1E8,-2.9999,0
R,2,1.E-4
MP,EX,1,1.e7
MP,NUXY,1,0.3

!  Keypoint Generation

K,1,0,0,0
K,2,45,0,0
K,3,45,-8,0
K,4,68,-8,0
K,5,68,12,0
K,6,45,12,0
K,7,45,30,0
K,8,38,30,0
K,9,28,36,0
K,10,12,36,0
K,11,8,20,0
K,12,0,20,0


!  Area Generation

A,1,2,3,4,5,6,7,8,9,10,11,12
cyl4,12,10,3
cyl4,56,0,3
ASBA,1,2
ASBA,4,3
LFILLT,6,5,2
AL,21,22,23
AADD,ALL

!  Meshing

SMRTSIZE,2 
MSHKEY,0
AMESH,ALL

!  Set up necessary nodal coordinate systems

LOCAL,11,1,12,10,0
LOCAL,12,1,56,0,0

!  Select the nodes around the the right holes
!  Prevent any radial motion

CSYS,12
NSEL,S,LOC,X,3,3
CM,hole2,NODE
NROTAT,ALL
D,ALL,UX
ALLSEL

!  Use CONTAC26 elements around the hole on the left

CSYS,11
N,5000,2.9999,5,0
N,6000,2.9999,175,0
TYPE,2
REAL,1
NSEL,S,LOC,X,3,3
NSEL,R,LOC,Y,5,175
NSEL,U,,,5000
NSEL,U,,,6000
*GET,NTOT,NODE,O,COUNT
*GET,N1,NODE,0,NUM,MIN
*DO,NV,1,NTOT
   E,N1,5000,6000
   N1=NDNEXT(N1)
*ENDDO
ALLSEL
D,5000,ALL
D,6000,ALL
CSYS,0

!  Pressure on line

SFL,9,PRES,100

!  Soft spring

N,7000,0,20.1,0
D,7000,ALL
TYPE,3
REAL,2
E,12,7000
ALLSEL